Instakill perma-perk (like in BO2) in Scripting

Well, basically yesterday I was bored and decided to make it. It is that red skull that appeared during instakill to a player who hadn't killed any zombie in the previous two instakills.

http://youtu.be/bQOZWvuxqh8

So let's start:
1. Copy your _zombiemode_powerups.gsc and _zombiemode.gsc from root/raw/maps to root/mods/MAPNAME/maps if you don't have them already.

2. Open _zombiemode_powerups.gsc. At the beginning of the file you might see this:

Code Snippet

Plaintext

PrecacheShader( "specialty_doublepoints_zombies" );
PrecacheShader( "specialty_instakill_zombies" );

So add this under:

Code Snippet

Plaintext

// Soy-yo's perma-insta-kill
PrecacheShader( "specialty_perma_instakill_zombies" );

Now find this function:

Code Snippet

Plaintext

insta_kill_powerup( drop_item )

Inside it, just below

Code Snippet

Plaintext

level notify( "powerup instakill" );
level endon( "powerup instakill" );

add this:

Code Snippet

Plaintext

// Soy-yo's perma-insta-kill
players = get_players();
for( i = 0; i < players.size; i++ ) {
    if( isAlive( players[i] ) )
        players[i].initialKills = players[i].kills;
    if( isDefined( players[i].zeroInstaKills ) && ( players[i].zeroInstaKills >= 2 
        || ( players[i].zeroInstaKills == 1 && randomInt(100) == 0 ) ) 
        && isAlive( players[i] ) )
            players[i] thread soy_yos_insta_kill_perma_perk_init();
}

And under this (inside the for loop):

Code Snippet

Plaintext

players[i] notify("insta_kill_over");

add this:

Code Snippet

Plaintext

// Soy-yo's perma-insta-kill
if( isDefined( players[i].initialKills ) && isAlive( players[i] ) && players[i].kills == players[i].initialKills ) { // the player hasn't killed anybody this time
    if( !isDefined( players[i].zeroInstaKills ) )
        players[i].zeroInstaKills = 1;
    else players[i].zeroInstaKills++;
} else if( isDefined( players[i].zeroInstaKills ) )
    players[i].zeroInstaKills = undefined;

Then, just after this function ends, add these functions:

Code Snippet

Plaintext

soy_yos_insta_kill_perma_perk_init() {
    
    self endon( "death" );
    self endon( "disconnect" );
    
    self.ignoreme = true;
    self thread soy_yos_perma_insta_kill_hud();
    self thread soy_yos_insta_kill_perma_perk_main();
    wait(15);
    self notify( "insta_kill_perma_perk_out" );
    self.ignoreme = false;
    
}

soy_yos_perma_insta_kill_hud() {
    hud = create_simple_hud( self );
    hud.foreground = true;   
    hud.sort = 2;
    hud.hidewheninmenu = false; 
    hud.alignX = "center"; 
    hud.alignY = "bottom";
    hud.horzAlign = "center"; 
    hud.vertAlign = "bottom";
    hud.y = hud.y - 80;
    hud.alpha = 1;
    hud setShader( "specialty_perma_instakill_zombies", 24, 24 );
    hud thread soy_yos_perma_insta_kill_hud_overlay();
    self waittill_any( "insta_kill_perma_perk_out","death","disconnect" );
    hud destroy_hud();
    hud notify( "hud_destroyed" );
}

soy_yos_perma_insta_kill_hud_overlay() {
    
    self endon( "hud_destroyed" );
    
    wait(10);
    
    for( i = 0; i < 5; i++ ) {
        self.alpha = 0;
        wait(.25);
        self.alpha = 1;
        wait(.25);
    }
    
    while(1) {
        self.alpha = 0;
        wait(.1);
        self.alpha = 1;
        wait(.1);
    }
}

soy_yos_insta_kill_perma_perk_main() {
    
    self endon( "insta_kill_perma_perk_out" );
    self endon( "death" );
    self endon( "disconnect" );
    
    while(1) {
        zombies = getAIArray( "axis" );
        for( i = 0; i < zombies.size; i++ ) {
            if( isAlive( self ) && !( self maps\_laststand::player_is_in_laststand() ) && distance( zombies[i].origin, self.origin ) < 30 ) {
                zombies[i] doDamage( zombies[i].health + 935, zombies[i].origin );
                zombies[i] maps\_zombiemode_spawner::zombie_head_gib();
                self maps\_zombiemode_score::add_to_player_score(50);
                wait(.3); // don't kill zombies too fast
            }
        }
        wait(.1);
    }
}

3. Now open _zombiemode.gsc and find this (it's inside "player_damage_override( eInflictor, eAttacker, iDamage, iDFlags, sMeansOfDeath, sWeapon, vPoint, vDir, sHitLoc, modelIndex, psOffsetTime )" function):

Code Snippet

Plaintext

if( isDefined( eAttacker.is_zombie ) && eAttacker.is_zombie )
{

and add this just below:

Code Snippet

Plaintext

// Soy-yo's instakill perma-perk
if( level.zombie_vars["zombie_insta_kill"] == 1 && isDefined( self.zeroInstaKills ) && self.zeroInstaKills >= 2 ) 
    self.zeroInstaKills = undefined;

4. Create your own shader or use mine:
MEGA
Mediafire
Extract the files, navigate to instakill_permaperk_shader/mods and rename "MAPNAME" to your map's name. Move everything into WaW root.
Then, include it in your mod.csv,

Code Snippet

Plaintext

// Edited For Perma Instakill
material,specialty_perma_instakill_zombies

tick it in IWD File List and build FF and IWD.

I think that's all. I haven't tested it in co-op, but there it shouldn't be any problem. Let me know if you find any bug, give credit to me if you use it in your map and have fun.

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
UGX V.I.P.
	Has released one or more maps to the UGX-Mods community which have been added to the UGX Map Manager.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.

UGX-Mods Login

Instakill perma-perk (like in BO2)