[Powerup] Random Perk in Scripts

Hey guys another small script/powerup for you guys, this basically took like no effort at all. So, hope you guys will enjoy/use it and thanks for actually adding more content into your map.

Model: Below in the Attachment Section
Extract to WaW root in AssMan convert the material and then the model.

Next up the scripts
_zombiemode_powerups.gsc
init_powerups()
(Add after your last powerup.)

Code Snippet

Plaintext

add_zombie_powerup( "perk",  		"zombie_bottle",	&"ZOMBIE_POWERUP_MAX_AMMO");

special_drop_setup()

Code Snippet

Plaintext

	//MM test  Change this if you want the same thing to keep spawning
//	powerup = "dog";
	switch ( powerup )
	{
	// Don't need to do anything special
	case "nuke":
	case "insta_kill":
	case "double_points":
	case "carpenter":
	//DUKIP - Added zombie perk.
	case "perk":
		break;

powerup_grab()

Code Snippet

Plaintext

					case "carpenter":
						level thread start_carpenter( self.origin );
						players[i] thread powerup_vo("carpenter");
						break;
					//DUKIP - Added zombie perk
					case "perk":
						players[i] thread zombie_perk_powerup();
						break;

powerup_vo(type)

Code Snippet

Plaintext

	switch(type)
	{
		case "nuke":
			if( vox_rand <= percentage )
			{
				//sound = "plr_" + index + "_vox_resp_dev_rare_" + rand;
				//iprintlnbold( "Whoopdedoo, rare Devil Response line" );
			}
			else
			{
				sound = "plr_" + index + "_vox_powerup_nuke_" + rand;
			}
			break;
		case "insta_kill":
			if( vox_rand <= percentage )
			{
				//sound = "plr_" + index + "_vox_resp_dev_rare_" + rand;
				//iprintlnbold( "Whoopdedoo, rare Devil Response line" );
			}
			else
			{
				sound = "plr_" + index + "_vox_powerup_insta_" + rand;
			}
			break;
		case "full_ammo":
			if( vox_rand <= percentage )
			{
				//sound = "plr_" + index + "_vox_resp_dev_rare_" + rand;
				//iprintlnbold( "Whoopdedoo, rare Devil Response line" );
			}
			else
			{
				sound = "plr_" + index + "_vox_powerup_ammo_" + rand;
			}
			break;
		case "double_points":
			if( vox_rand <= percentage )
			{
				//sound = "plr_" + index + "_vox_resp_dev_rare_" + rand;
				//iprintlnbold( "Whoopdedoo, rare Devil Response line" );
			}
			else
			{
				sound = "plr_" + index + "_vox_powerup_double_" + rand;
			}
			break;
		case "carpenter":
			if( vox_rand <= percentage )
			{
				//sound = "plr_" + index + "_vox_resp_dev_rare_" + rand;
				//iprintlnbold( "Whoopdedoo, rare Devil Response line" );
			}
			else
			{
				sound = "plr_" + index + "_vox_powerup_carp_" + rand;
			}
			break;
		//DUKIP - Add zombie perk, don't do any plr vox sounds.
		case "perk":
			break;
	}

Somewhere at the bottom of the GSC paste this in.

Code Snippet

Plaintext

zombie_perk_powerup()
{
	self endon("disconnect");

	player = self;
	perk = getRandomPerk(player);
	//DUKIP - Make sure player doesn't have the perk and perk is defined.
	if(player HasPerk(perk) || !IsDefined(perk))
	{
		//DUKIP - 50/50 chance of playing the sound.
		if(cointoss())
			player PlayLocalSound("sam_nospawn");
		return;
	}

	//DUKIP - Moved this var to above the perk bottle give as there was a chance of getting "dual" perks.
	player.is_drinking = 1;

	// do the drink animation
	gun = player maps\_zombiemode_perks::perk_give_bottle_begin( perk );

	player waittill_any( "fake_death", "death", "player_downed", "weapon_change_complete" );

	// restore player controls and movement
	player maps\_zombiemode_perks::perk_give_bottle_end( gun, perk );
	player.is_drinking = undefined;
	// TODO: race condition?
	if ( player maps\_laststand::player_is_in_laststand() )
		return;

	player SetPerk( perk );
	player thread maps\_zombiemode_perks::perk_vo(perk);
	player setblur( 4, 0.1 );
	wait(0.1);
	player setblur(0, 0.1);

	if(perk == "specialty_armorvest")
	{
		player.maxhealth = level.zombie_vars["zombie_perk_juggernaut_health"];
		player.health = level.zombie_vars["zombie_perk_juggernaut_health"];
	}

	player maps\_zombiemode_perks::perk_hud_create( perk );

	//stat tracking
	player.stats["perks"]++;

	bbPrint( "zombie_uses: playername %s playerscore %d round %d cost %d name %s x %f y %f z %f type perk",
		player.playername, player.score, level.round_number, 0, perk, self.origin );

	player thread maps\_zombiemode_perks::perk_think( perk );
}

getRandomPerk(player)
{
	//DUKIP - Make sure we're not drinking anything already.
	if(IsSubStr(player getCurrentWeapon(), "bottle") || (IsDefined(player.is_drinking) && player.is_drinking))
		return;

	all_perks = [];
	all_perks[0] = "specialty_armorvest";
	all_perks[1] = "specialty_quickrevive";
	all_perks[2] = "specialty_fastreload";
	all_perks[3] = "specialty_rof";
	//all_perks[NUM] = "specialty_XXXX";

	all_perks = array_randomize(all_perks);

	thePerk = random(all_perks);

	return thePerk;
}

dlc3_code.gsc
include_powerups()
After last include_powerup() add this:

Code Snippet

Plaintext

include_powerup( "perk" );

That's it, enjoy!


	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha


	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha


	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha


	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha


	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.

UGX-Mods Login

[Powerup] Random Perk

Attachments: