How to Replace Round Chalk HUD with Numbers in Scripting

Guide to replacing chalk hud with numbers

Instructions

Step 1: Navigate to your raw/maps/ folder and copy _zombiemode.gsc into your mods/your_mod/maps folder
-----------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
Step 2: Open _zombiemode.gsc and locate this thread

Code Snippet

cpp

chalk_one_up()

-----------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
Step 3: Replace the entire thread of chalk_one_up() with the this

Code Snippet

cpp

chalk_one_up()
{
    if(!IsDefined(level.doground_nomusic))
    {
        level.doground_nomusic = 0;
    }
    if( level.first_round )
    {
        intro = true;
    }
    else
    {
        intro = false;
    }
    round = undefined;    
    if( intro )
    {
        round = create_simple_hud();
        round.alignX = "center"; 
        round.alignY = "bottom";
        round.horzAlign = "center"; 
        round.vertAlign = "bottom";
        round.fontscale = 16;
        round.color = ( 1, 1, 1 );
        round.x = 0;
        round.y = -350;
        round.alpha = 0;
        round SetText( &"ZOMBIE_ROUND" );
        round FadeOverTime( 1 );
        round.alpha = 1;
        wait( 1 );
        round FadeOverTime( 3 );
        round.color = ( 0.423, 0.004, 0 );
    }
    hud = undefined;
    if( level.round_number > 0 )
    {
        hud = level.chalk_hud1;
        hud.fontscale = 30;
        hud SetValue( level.round_number );
    }
    if( intro )
    {
        hud.alpha = 0;
        hud.horzAlign = "center";
        hud.x = -12;
        hud.y = -300;
    }
    hud FadeOverTime( 0.5 );
    hud.alpha = 0;
    wait( 0.5 );
    if(IsDefined(level.eggs) && level.eggs !=1 )
    {
        if(level.doground_nomusic ==0 )
        {
            setmusicstate("round_begin");
        }
    }
    hud FadeOverTime( 0.5 );
    hud.alpha = 1;
    if( intro )
    {
        wait( 3 );
        if( IsDefined( round ) )
        {
            round FadeOverTime( 1 );
            round.alpha = 0;
        }
        wait( 0.25 );
        level notify( "intro_hud_done" );
        hud MoveOverTime( 1.75 );
        hud.horzAlign = "left";
        hud.x = 15;
        hud.y = -10;
        wait( 2 );
        round destroy_hud();
    }
}

-----------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
Step 4: Locate the thread named round_start(). Inside that thread, you will find the following

Code Snippet

cpp

level.chalk_hud1 = create_chalk_hud();
level.chalk_hud2 = create_chalk_hud( 64 );

Code Snippet

cpp

// level.chalk_hud2 = create_chalk_hud( 64 );

UGX-Mods Login

How to Replace Round Chalk HUD with Numbers